(split) Merge branch 'cmake_reorder_files2' into 'master'

Cmake reorder files2

See merge request !3

.clang-format

+BasedOnStyle: LLVM
+IndentWidth: 8
+UseTab: ForIndentation
+BreakBeforeBraces: Linux
+AllowShortIfStatementsOnASingleLine: false
+IndentCaseLabels: false
+ColumnLimit: 110
+
+AlignConsecutiveAssignments: true
+AlignConsecutiveDeclarations: true
+AccessModifierOffset: 0
+NamespaceIndentation: Inner
\ No newline at end of file

.gitlab-ci.yml

+image: gcc
+variables:
+  GIT_SUBMODULE_STRATEGY: normal
+  
+stages:
+  - build
+  - doc
+
+before_script:
+  - git status
+  - mkdir -p build/
+  - cd build/
+
+compile_cpp_api:
+  stage: build
+  script:
+    - cmake ..
+    - cmake --build .
+    
+pages:
+  stage: doc
+  script:
+    - cmake ..
+    - cmake --build . --target doc
+    - mv doc/html/ ../public/
+  artifacts:
+    paths:
+      - public
+  only:
+    - master
+    - cmake
\ No newline at end of file

CMakeLists.txt

+if(NOT DEFINED PROJECT_NAME)
+  cmake_minimum_required(VERSION 3.7.2)
+  
+  # Project name and version
+  project(cameo VERSION 0.3.0 LANGUAGES CXX)
+endif()
+
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+if(NOT DEFINED BUILD_SHARED_LIBS)
+  set(BUILD_SHARED_LIBS True)
+endif()
+
+if(NOT DEFINED CMAKE_CXX_STANDARD)
+  # specify the C++ standard
+  set(CMAKE_CXX_STANDARD 11)
+  set(CMAKE_CXX_STANDARD_REQUIRED True)
+endif()
+
+
+# fix the RPATH for the linker
+#if(not APPLE)
+#  set(CMAKE_INSTALL_RPATH $ORIGIN)
+#endif()
+
+#------------------------------------------------------------
+# Dependencies
+#------------------------------------------------------------
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR})
+find_package(ZeroMQ REQUIRED)
+find_package(Rapidjson REQUIRED)
+
+#------------------------------------------------------------
+# Libraries
+#------------------------------------------------------------
+
+
+#---------------
+# Files
+file(GLOB_RECURSE CAMEO_SOURCE_FILES "src/*.cpp")
+#file(GLOB CAMEO_PUBLIC_HEADER_FILES "./*.h")
+#message(${CAMEO_PUBLIC_HEADER_FILES})
+#message(${CAMEO_SOURCE_FILES})
+
+add_library(cameo ${CAMEO_SOURCE_FILES})
+target_link_libraries(cameo PRIVATE zmq)
+target_include_directories(cameo
+  PRIVATE ${CMAKE_CURRENT_BINARY_DIR} # this is to get protobuf messages
+  PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src/ # all the private headers
+  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include> 
+  PUBLIC $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+  )
+#target_compile_features(cameo PUBLIC cxx_std_11)
+set_target_properties(cameo PROPERTIES
+  SOVERSION ${PROJECT_VERSION_MAJOR}
+  VERSION ${PROJECT_VERSION}
+  )
+
+message(${PROJECT_VERSION_MAJOR})
+message(${PROJECT_VERSION})
+#---------------
+# Library version
+write_basic_package_version_file(cameoConfigVersion.cmake
+  COMPATIBILITY SameMajorVersion
+  VERSION ${PROJECT_VERSION}
+  )
+
+
+#------------------------------------------------------------
+# Install
+#------------------------------------------------------------
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/cameoConfigVersion.cmake
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake)
+
+# this is to install the headers
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}
+  )
+
+# in CMake 3.14 you just need #install(TARGETS cameo)
+install(TARGETS cameo
+  EXPORT cameoexport
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} # windows
+    COMPONENT cameo_Runtime
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} # dynamic
+    COMPONENT cameo_Runtime
+#    NAMELINK_COMPONENT cameo_Development #from CMake 3.12
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} # static
+    COMPONENT cameo_Development
+  PUBLIC_HEADER  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+  INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+  )
+
+
+# This makes the project importable from the install directory
+# Put config file in per-project dir (name MUST match), can also
+# just go into 'cmake'.
+install(EXPORT cameoexport
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake
+  FILE ${PROJECT_NAME}Config.cmake 
+  )
+# makes the project importable from the build directory
+export(TARGETS cameo FILE ${CMAKE_BINARY_DIR}/${PROJECT_NAME}Config.cmake)
+
+# the install_manifest file is created only after the installation....
+#install(FILES ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
+#  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake
+#  RENAME cameo_install_manifest.txt
+#  )
+
+
+#enable_testing()
+#add_subdirectory(test)
+
+
+#include(CMakeFindDependencyMacro)
+#find_dependency(
+#include("${CMAKE_CURRENT_LIST_DIR}/cameo.cmake")
+################ Doc
+find_package(Doxygen)
+if (DOXYGEN_FOUND)
+  # set input and output files
+  set(DOXYGEN_IN ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in)
+  set(DOXYGEN_OUT ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile)
+  
+  # request to configure the file
+  configure_file(${DOXYGEN_IN} ${DOXYGEN_OUT} @ONLY)
+  message("Doxygen build started")
+  
+  # note the option ALL which allows to build the docs together with the application
+  add_custom_target( doc 
+    COMMAND ${DOXYGEN_EXECUTABLE} ${DOXYGEN_OUT}
+    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+    COMMENT "Generating API documentation with Doxygen"
+    VERBATIM )
+else (DOXYGEN_FOUND)
+  message("Doxygen need to be installed to generate the doxygen documentation")
+endif (DOXYGEN_FOUND)
+
+

FindRapidjson.cmake

+#.rst:
+# FindRapidjson
+# --------
+#
+# Find the native rapidjson includes and library.
+#
+# IMPORTED Targets
+# ^^^^^^^^^^^^^^^^
+#
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This module defines the following variables:
+#
+# ::
+#
+#   Rapidjson_INCLUDE_DIRS   - where to find rapidjson/document.h, etc.
+#   Rapidjson_LIBRARIES      - List of libraries when using rapidjson.
+#   Rapidjson_FOUND          - True if rapidjson found.
+#
+# ::
+#
+#
+# Hints
+# ^^^^^
+#
+# A user may set ``RAPIDJSON_ROOT`` to a rapidjson installation root to tell this
+# module where to look.
+
+#=============================================================================
+# Copyright 2018 OWenT.
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+# This file have been downloaded from: https://raw.githubusercontent.com/owent-contrib/rapidjson/aa4c227/contrib/cmake/FindRapidjson.cmake
+
+unset(_RAPIDJSON_SEARCH_ROOT_INC)
+unset(_RAPIDJSON_SEARCH_ROOT_LIB)
+
+# Search RAPIDJSON_ROOT first if it is set.
+if (Rapidjson_ROOT)
+  set(RAPIDJSON_ROOT ${Rapidjson_ROOT})
+endif()
+
+if(RAPIDJSON_ROOT)
+  set(_RAPIDJSON_SEARCH_ROOT_INC PATHS ${RAPIDJSON_ROOT} ${RAPIDJSON_ROOT}/include NO_DEFAULT_PATH)
+endif()
+
+# Try each search configuration.
+find_path(Rapidjson_INCLUDE_DIRS    NAMES rapidjson/document.h  ${_RAPIDJSON_SEARCH_ROOT_INC})
+
+mark_as_advanced(Rapidjson_INCLUDE_DIRS)
+
+# handle the QUIETLY and REQUIRED arguments and set RAPIDJSON_FOUND to TRUE if
+# all listed variables are TRUE
+include("FindPackageHandleStandardArgs")
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(Rapidjson
+  REQUIRED_VARS Rapidjson_INCLUDE_DIRS
+  FOUND_VAR Rapidjson_FOUND
+)
+
+if(Rapidjson_FOUND)
+    set(RAPIDJSON_FOUND ${Rapidjson_FOUND})
+endif()

FindZeroMQ.cmake

+# from https://github.com/zeromq/azmq/blob/master/config/FindZeroMQ.cmake
+# commit 0d4b8b0
+# Find ZeroMQ Headers/Libs
+
+# Variables
+# ZMQ_ROOT - set this to a location where ZeroMQ may be found
+#
+# ZeroMQ_FOUND - True of ZeroMQ found
+# ZeroMQ_INCLUDE_DIRS - Location of ZeroMQ includes
+# ZeroMQ_LIBRARIES - ZeroMQ libraries
+
+include(FindPackageHandleStandardArgs)
+
+if (NOT ZMQ_ROOT)
+    set(ZMQ_ROOT "$ENV{ZMQ_ROOT}")
+endif()
+
+if (NOT ZMQ_ROOT)
+    find_path(_ZeroMQ_ROOT NAMES include/zmq.h)
+else()
+    set(_ZeroMQ_ROOT "${ZMQ_ROOT}")
+endif()
+
+find_path(ZeroMQ_INCLUDE_DIRS NAMES zmq.h HINTS ${_ZeroMQ_ROOT}/include)
+
+if (ZeroMQ_INCLUDE_DIRS)
+    set(_ZeroMQ_H ${ZeroMQ_INCLUDE_DIRS}/zmq.h)
+
+    function(_zmqver_EXTRACT _ZeroMQ_VER_COMPONENT _ZeroMQ_VER_OUTPUT)
+        set(CMAKE_MATCH_1 "0")
+        set(_ZeroMQ_expr "^[ \\t]*#define[ \\t]+${_ZeroMQ_VER_COMPONENT}[ \\t]+([0-9]+)$")
+        file(STRINGS "${_ZeroMQ_H}" _ZeroMQ_ver REGEX "${_ZeroMQ_expr}")
+        string(REGEX MATCH "${_ZeroMQ_expr}" ZeroMQ_ver "${_ZeroMQ_ver}")
+        set(${_ZeroMQ_VER_OUTPUT} "${CMAKE_MATCH_1}" PARENT_SCOPE)
+    endfunction()
+
+    _zmqver_EXTRACT("ZMQ_VERSION_MAJOR" ZeroMQ_VERSION_MAJOR)
+    _zmqver_EXTRACT("ZMQ_VERSION_MINOR" ZeroMQ_VERSION_MINOR)
+    _zmqver_EXTRACT("ZMQ_VERSION_PATCH" ZeroMQ_VERSION_PATCH)
+
+    message(STATUS "ZeroMQ version: ${ZeroMQ_VERSION_MAJOR}.${ZeroMQ_VERSION_MINOR}.${ZeroMQ_VERSION_PATCH}")
+
+    # We should provide version to find_package_handle_standard_args in the same format as it was requested,
+    # otherwise it can't check whether version matches exactly.
+    if (ZeroMQ_FIND_VERSION_COUNT GREATER 2)
+        set(ZeroMQ_VERSION "${ZeroMQ_VERSION_MAJOR}.${ZeroMQ_VERSION_MINOR}.${ZeroMQ_VERSION_PATCH}")
+    else()
+        # User has requested ZeroMQ version without patch part => user is not interested in specific patch =>
+        # any patch should be an exact match.
+        set(ZeroMQ_VERSION "${ZeroMQ_VERSION_MAJOR}.${ZeroMQ_VERSION_MINOR}")
+    endif()
+
+    if (NOT ${CMAKE_CXX_PLATFORM_ID} STREQUAL "Windows")
+        find_library(ZeroMQ_LIBRARIES NAMES zmq HINTS ${_ZeroMQ_ROOT}/lib)
+    else()
+        find_library(
+            ZeroMQ_LIBRARY_RELEASE
+            NAMES
+                libzmq
+                "libzmq-${CMAKE_VS_PLATFORM_TOOLSET}-mt-${ZeroMQ_VERSION_MAJOR}_${ZeroMQ_VERSION_MINOR}_${ZeroMQ_VERSION_PATCH}"
+            HINTS
+                ${_ZeroMQ_ROOT}/lib
+            )
+
+        find_library(
+            ZeroMQ_LIBRARY_DEBUG
+            NAMES
+                libzmq_d
+                "libzmq-${CMAKE_VS_PLATFORM_TOOLSET}-mt-gd-${ZeroMQ_VERSION_MAJOR}_${ZeroMQ_VERSION_MINOR}_${ZeroMQ_VERSION_PATCH}"
+            HINTS
+                ${_ZeroMQ_ROOT}/lib)
+
+        # On Windows we have to use corresponding version (i.e. Release or Debug) of ZeroMQ because of `errno` CRT global variable
+        # See more at http://www.drdobbs.com/avoiding-the-visual-c-runtime-library/184416623
+        set(ZeroMQ_LIBRARIES optimized "${ZeroMQ_LIBRARY_RELEASE}" debug "${ZeroMQ_LIBRARY_DEBUG}")
+    endif()
+endif()
+
+find_package_handle_standard_args(ZeroMQ FOUND_VAR ZeroMQ_FOUND
+    REQUIRED_VARS ZeroMQ_INCLUDE_DIRS ZeroMQ_LIBRARIES
+    VERSION_VAR ZeroMQ_VERSION)
+
+if (ZeroMQ_FOUND)
+    mark_as_advanced(ZeroMQ_INCLUDE_DIRS ZeroMQ_LIBRARIES ZeroMQ_VERSION
+        ZeroMQ_VERSION_MAJOR ZeroMQ_VERSION_MINOR ZeroMQ_VERSION_PATCH)
+endif()

README.md

+
+## Dependencies 
+
+### CENTOS 8 
+
+List of packages:
+ - cppzmq-devel
+ - rapidjson-devel
+ 
+```
+pkgs="zeromq-devel rapidjson-devel"
+yum install -y $pkgs
+```
+
+### Debian XXX
+
+
+
+### Ubuntu XXX
+sudo apt install  libzmq3-dev rapidjson-dev
+
+
+## Compilation instructions
+
+```
+mkdir build/
+cd build/
+cmake ..
+cmake --build .
+```
+
+# To Do
+ - [ ] remove zmq deprecated methods
+ ```
+ /opt/panosc/cameo/src/impl/SubscriberImpl.cpp:210:36: warning: ‘bool zmq::detail::socket_base::recv(zmq::message_t*, int)’ is deprecated: from 4.3.1, use recv taking a reference to message_t and recv_flags [-Wdeprecated-declarations]
+    m_subscriber->recv(message.get());
+                                    ^
+In file included from /opt/panosc/cameo/src/impl/SocketWaitingImpl.h:23,
+                 from /opt/panosc/cameo/src/impl/SubscriberImpl.h:20,
+                 from /opt/panosc/cameo/src/impl/SubscriberImpl.cpp:17:
+/usr/include/zmq.hpp:1267:10: note: declared here
+     bool recv(message_t *msg_, int flags_ = 0)
+          ^~~~
+```